1 空间回归模型的应用
1.1 数据
这里以2011—2018年我国30个地区的面板数据为例，研究劳动者受教育年限、对外贸易和外商直接投资对GDP的影响！
1.2 准备空间权重矩阵
常见的空间权重矩阵有01权重矩阵、地理距离权重矩阵和经济距离权重矩阵。
本例中的数据为我国30个地区的截面数据，提供了01空间权重矩阵和地理距离倒数的权重矩阵。
由于stata不同版本的数据文件可能存在不兼容的情况，不方便分享，所以空间权重矩阵均存放在Excel数据文件中。为了在后续分析时调用，需要先将其复制粘贴到自己用的stata版本中，并保存为stata数据文件。
其中，01权重矩阵保存为binaryW.dta；地理距离权重矩阵保存为distanceW.dta。后续分析时需要调用这两个空间权重。
在保存空间权重时，需要注意空间权重中各地区的排列顺序，后续回归数据中各地区的排列顺序需要与之一致。
将Excel中的01空间权重矩阵复制到stata中并另存为binaryW.dta数据文件
将Excel中的地理距离空间权重矩阵复制到stata中并另存为distanceW.dta数据文件
1.3 录入数据及面板格式设定
打开回归数据编辑窗口，将数据从Excel中复制到Stata，注意粘贴时选择“将第一行作为变量名”。
切换到binaryW.dta、distanceW.dta文件所在目录：
cd D:\Desktop
设置面板数据格式：
encode prov,g(id)
xtset id year
sort year prov
排序后发现每年各地区的排序与空间权重中各地区的排序不一致，所以需要对数据进行处理！
新打开一个stata数据文件，将空间权重矩阵中各地区的排序粘贴进行，并生成顺序变量：ord，然后将该数据集保存为ord.dta数据文件！
将面板数据与上述生成的ord.dta数据进行匹配：
merge m:m prov using ord.dta
按照year和ord变量进行排序：
sort year ord
此时，数据集中每年各地区的排序与空间权重中各地区的排序一致，可以进行后续分析！
1.4 空间自相关检验
在截面数据的空间回归中，我们采用spatgsa和spatlsa命令来进行空间自相关检验，这两个命令只适用于截面数据。而目前仍没有针对面板数据的自相关检验命令。所以这里需要根据面板数据的结构将空间权重矩阵进行扩展（例如原空间权重为30*30的矩阵，面板数据有 8年，那么生成的新的空间权重为240*240的矩阵！），然后继续采用spatgsa和spatlsa命令来进行空间自相关检验。
安装面板空间矩阵生成命令：spwmatrix
ssc install spwmatrix
根据原始空间权重生成新的分块对称矩阵：
spwmatrix import using binaryW.dta,wname(bW) dta xtw(8)
spwmatrix import using binaryW.dta,wname(stdW) dta xtw(8) row xport(newW,txt)
spwmatrix命令能够通过截面空间权重来生成面板数据对应的空间权重；xtw(8)表示面板数据有8年；dta表示从dta文件导入截面空间权重。row和xport()参数可选，row表示进行“行-标准化”；xport()将生成的面板数据空间权重导出到新的文件中。
在计算空间相关系数Getis and Ord's G时，不能对空间权重进行“行-标准化”。但是在进行局部空间相关系数绘图时，需要对空间权重进行“行-标准化”，所以最好生成两个空间权重矩阵。
另外，如果不进行“行-标准化”，生成的是对称矩阵（矩阵的一半没有数据）；如果进行行标准化，则是正常的矩阵。
计算全局自相关系数：
spatgsa pgdp open, weights(bW) moran geary twotail
估计Getis and Ord's G相关系数需要空间权重是非对称矩阵和非标准化矩阵，这里生成的bW和stdW均不满足，所以这里仅计算Moran's I、Geary's c自相关系数！
估计结果中，pgdp和open两个变量的Moran's I、Geary's c自相关系数显著，表明这两个变量存在空间自相关。一般来说，只要莫兰指数显著，就可以认为存在空间自相关，具体取决于自己的研究需求。
计算局部自相关系数并绘制局部自相关图：
spatlsa pgdp, weights(stdW) moran geary twotail graph(moran)
计算局部自相关时一次只能计算一个变量，这里计算的是pgdp，其他变量也可以采用相同的方法进行，这里不再演示！
绘制局部莫兰自相关图时，空间权重必须“行-标准化”，所以这里选用的是stdW空间权重！
局部空间自相关的估计结果非常多，看起来比较杂乱，所以一般用局部空间自相关图来观察空间自相关性。
在局部莫兰自相关图中，第一和第三象限表示正相关，第二和第四象限表示负相关！
本例中多数样本点位于第一和第三现象，且呈现一定的线性趋势，所以认为存在正的空间自相关。
1.5 空间效应诊断
进行OLS估计，然后进行空间效应诊断：
reg pgdp pfdi open eduyear
spatdiag, weights(bW)
需要先运行reg命令，才能运行空间效应诊断命令：spatdiag。这里不再展示reg回归的结果，仅展示空间效应诊断的结果。
空间效应诊断结果中，分别给出了空间误差（Spatial error）和空间自相关（Spatial lag）的检验。结果显示，空间误差（Spatial error）中3个统计量有两个显著；空间自相关（Spatial lag）中2个统计量均显著。因而OLS估计中存在空间自相关性！
对于面板数据来说，空间回归模型不止空间误差（Spatial error）和空间自相关（Spatial lag）两种，所以空间效应诊断仅作为参考。主要还是通过面板数据空间回归的结果来判断！
1.6 估计面板空间回归
设置stata中矩阵最大维度为1000：
set matsize 1000
导入空间权重矩阵：
spwmatrix import using binaryW.dta,wname(crossbW) dta row
前面计算空间自相关系数时，需要将原始空间权重矩阵按照面板数据结构进行扩展。但是面板空间回归的xsmle命令可以自动将原始的空间权重转换为面板数据所需要的形式，所以这里重新采用spwmatrix命令导入原始空间权重矩阵（注意不加xtw(8),同时必须加row进行“行-标准化”！）。
安装面板空间回归的命令：xsmle
ssc install xsmle
xsmle命令中参数fe表示估计效应，re表示随机效应；type(ind)表示对个体控制、type(time)表示对时间控制、type(both)表示同时对个体时间进行控制；effects表示列出空间面板回归的直接效应、间接效应和总效应。
目前，面板空间回归命令xsmle仅支持平衡面板数据！
由于面板空间回归模型形式非常多，但解释基本类似，所以这里给展示1个模型的估计结果，其余模型仅给出估计代码，不再展示估计结果！
1.6.1 估计空间自回归模型（sar）
个体固定效应：
xsmle pgdp eduyear pfdi open, wmat(crossbW) model(sar) fe type(ind) nsim(500) effects
在面板空间回归中，系数的回归结果很难进行解释，所以一般需要将回归结果分解为直接效应、间接效应和总效应！
本例中，rho的系数显著，因而表明模型中存在空间自回归性。
直接效应中，eduyear的系数为1.317967，且显著。表明本地人口受教育程度提高1年，可以使本地区人均gdp提高1.317967单位。
间接效应中，eduyear的系数为1.386454，且显著。表明相邻地区人口受教育程度提高1年，可以使本地区人均gdp提高1.386454单位。
总效应是直接效应和间接效应之和。
其余解释变量的解释与之类似！
时间固定效应命令（结果不再展示）：
xsmle pgdp eduyear pfdi open, wmat(crossbW) model(sar) fe type( time) nsim(500) effects
个体时间双固定效应命令（结果不再展示）：
xsmle pgdp eduyear pfdi open, wmat(crossbW) model(sar) fe type(both) nsim(500) effects
个体随机效应命令（结果不再展示）：
xsmle pgdp eduyear pfdi open, wmat(crossbW) model(sar) re type(ind) nsim(500) effects
1.6.2 估计空间自相关模型（sac）
sac模型只能估计固定效应，不能估计随机效应！
个体固定效应：
xsmle pgdp eduyear pfdi open, wmat(crossbW) emat(crossbW) model(sac) fe type(ind) nsim(500) effects
1.6.3 估计空间杜宾模型（sdm）
个体固定效应：
xsmle pgdp eduyear pfdi open, wmat(crossbW) model(sdm) fe type(ind) nsim(500) effects
个体随机效应：
xsmle pgdp eduyear pfdi open, wmat(crossbW) model(sdm) re type(ind) nsim(500) effects
1.6.4 估计空间误差模型（sem）
sem模型无法给出直接效应、间接效应和总效应!
个体固定效应：
xsmle pgdp eduyear pfdi open, emat(crossbW) model(sem) fe type(ind) nsim(500) effects
个体随机效应：
xsmle pgdp eduyear pfdi open, emat(crossbW) model(sem) re type(ind) nsim(500) effects
1.7 进一步研究
为了回归的稳健性，可以继续采用地理距离空间权重进行空间相关性检验、空间效应诊断和面板空间回归。操作步骤与01空间权重一致，这里不再演示！