如果我们能够获得政策执行前后n期的数据，那么可以采用传统did-多期数据的方法来进行研究。传统did-多期数据与两期数据的分析基本一致，并且由于数据为多期，所以可以对did的平行趋势进行检验。
1 传统DID模型的形式
2 传统DID模型的应用
2.1 数据
外国投资者被称为“聪明的投资者”，但由于我国资本市场的开发程度较低，2014年之前外国投资者不能直接参与我国股市。2014年，我国推出了沪港通制度（一部分上市公司被选为沪港通标的），沪港通股票可以被外国投资者买卖。这为研究外资介入对我国上市企业的影响提供了自然实验数据。
这里我们收集了2011年至2017年我国上市工业企业的财务数据，以及是否为沪港通标的数据，采用DID方法来研究外资介入对企业资产总计的影响。
2.2 录入数据
打开数据编辑窗口，将数据从Excel中复制到Stata，注意粘贴时选择“将第一行作为变量名”
2.3 数据整理
护港通在2014年开通，但是有些上市企业在2015年、2016年..才逐渐成为沪港通标的。传统did模型主要是比较政策执行年2014年前后的变化，所以在其他年份逐渐成为沪港通标的的上市企业会造成干扰，所以需要将其删除！
删除干扰数据：
g temp=1 if 沪港通2014=="是" && 沪港通2015=="是" && 沪港通2016=="是" && 沪港通2017=="是"
replace temp=0 if 沪港通2014=="否" && 沪港通2015=="否" && 沪港通2016=="否" && 沪港通2017=="否"
drop if temp==.
drop temp
转换为面板数据布局：
reshape long 资产总计 资产负债率 流动比率 总资产周转率 roe 沪港通,i( 证券代码 ) j(year)
由于沪港通仅针对上交所的股票，所以需要删除深交所的股票：
g temp=substr( 证券代码,8,2)
drop if temp=="SZ"
drop temp
变量变换：
encode 证券代码,g(id)
g lnage=ln(year-成立年)
rename 资产总计 asset
rename 资产负债率 debt
rename 流动比率 liquit
rename 总资产周转率 turnover
rename 沪港通 hgt
2.4 did数据处理
生成时间变量：
g time=0
replace time=1 if year>=2014
生成处理效应变量：
g temp=1 if hgt=="是"
bys id: egen treated=sum(temp)
replace treated=1 if treated>1
drop temp
生成时间和处理效应的交互项：
g did=time*treated
2.5 混合面板的did估计
首先估计外资介入对企业资产负债率的影响，和传统did-两期数据中的例子进行对比！
估计did模型：
reg debt did time treated,r
在估计结果中，did变量的系数不显著，所以采用多期数据后，外资介入对企业资产负债率的影响不显著。
接着，估计外资介入对企业资产总计的影响。
估计did模型：
g lnasset=ln(asset)
reg lnasset did time treated,r
估计结果中，did变量的系数为正数，且显著，因而外资介入有助于提高企业总资产。
这里不再演示加入控制变量后的结果！
2.6 采用外部命令diff进行估计
did模型估计：
diff lnasset, t(treated) p(time) robust
diff的估计结果与混合面板估计结果一致。
2.7 面板固定效应的DID模型估计
面板数据设定及did估计：
xtset id year
xtreg lnasset did i.year,fe
在估计结果中，did变量的系数依然显著为正数。
2.8 平行趋势检验！
2.8.1 回归方式的检验
生成政策执行前后3期的检验变量：
g n = year-2014
g b3 = (n==-3 & treated==1)
g b2 = (n==-2 & treated==1)
g b1 = (n==-1 & treated==1)
g policyyear = (n==0 & treated==1)
g a1 = (n==1 & treated==1)
g a2 = (n==2 & treated==1)
g a3 = (n==3 & treated==1)
估计各期的效应：
xtreg lnasset time treated b3 b2 b1 policyyear a1 a2 a3 i.year, fe
est sto reg
在估计结果中，政策执行前3期和前2期检验变量的系数不显著，表明政策执行前，外资介入和非外资介入企业的总资产变动趋势一样。政策执行后的0期，1期，2期，3期检验变量的系数均显著为正数，表明政策执行后，外资介入企业的总资产显著提高。当然，本例中政策执行前1期检验变量的系数也显著为正数，这与期望的结果不一致；但只要多数检验变量的结果与预期一致，仍可以表明平行趋势假设成立。
2.8.1 绘图方式的检验
安装coefplot命令：
ssc install coefplot
绘制图形：
coefplot reg,keep(b3 b2 b1 policyyear a1 a2 a3) vertical recast(connect) yline(0)
在图形中，政策执行前3期和前2期的散点围绕0值波动，表明政策执行前，外资介入和非外资介入企业的总资产变动趋势一样。政策执行后0期，1期，2期，3期的散点显著高于0值 ，表明政策执行后，外资介入企业的总资产显著提高。这与回归方式的结论一致。